Riot Women (2025)

Τρέχοντας το παρακάτω αρχειάκι, επιλέγετε την αυτόματη ή μη, αλλαγή ή επαναφορά στην προεπιλογή των DNS, πατώντας απλά τον αντίστοιχο αριθμό στη λίστα του μενού.
πχ:

Αντιγράψτε-Σώστε τον παρακάτω («ανοιχτό») κώδικα σε ένα νέο αρχείο κειμένου,
και ονομάστε το σε SetDNSservers[v1.1-GR].bat
Εκτέλεση: δεξ.κλικ στο αρχείο -> εκτέλεση ως Διαχειριστής /!\

:::::::::: Αυτή η δέσμη εντολών (.bat) πρόκειται να αλλάξει τους DNS διακομιστές σας. ::::::::::
:::::::::: Ισχύει/εφαρμόζεται σε όλες τις εκδόσεις των Windows (Vista,7,8,10,11). ::::::::::
@echo off
mode con: cols=76 lines=47&&color 1f
title SetDNSservers[v1.1-GR]
:: Οι ακόλουθες δύο γραμμές αντιπροσωπεύουν την υποστήριξη χαρακτήρων, οποιωνδήποτε Τοπικών Γλωσσών (όπως εδώ οι ελληνικοί).
setlocal ΕnableΕxtensions
%WinDir%\System32\chcp.com 65001 >nul
:Start
cls
:: Λίστα Προσαρμογέων Δικτύου
echo.
echo. Λίστα Προσαρμογέων Δικτύου (Προσαρμογείς Internet)
netsh interface show interface
echo.==========================================================================
:: Εμφάνιση, κατάσταση, τύπος και ρύθμιση Προσαρμογέων Δικτύου
setlocal EnableDelayedExpansion
for /F "skip=3 tokens=1,2,3* delims= " %%G in ('netsh interface show interface') DO (
if /i "%%G"=="Enabled" (
if /i "%%H"=="Connected" (
set "InterfaceName=%%J"
)))

:: Επιλογή Προσαρμογέα Δικτύου (Interface Name)
echo. Γράψτε το όνομα Προσαρμογέα Δικτύου (Interface Name)
echo. στον οποίο επιθυμείτε να αλλάξετε τις ρυθμίσεις DNS,
echo. ή αφήστε το κενό και πατήστε [Enter] για το "%InterfaceName%"
set /p InterfaceName=Όνομα Προσαρμογέα Δικτύου (Interface Name):
if /i "!InterfaceName!"=="" set InterfaceName=%InterfaceName%
echo "%InterfaceName%"
echo.==========================================================================
echo.&&echo. ΠΡΟΕΙΔΟΠΟΙΗΣΗ ^^! ΑΠΕΝΕΡΓΟΠΟΙΗΣΤΕ ΠΡΩΤΑ ΤΟ VPN ^^! (Άν είναι ανοιχτό)
echo.&&echo.-----------------------------------------------------------
---------------

:: Επιλογή αυτόματης, ή μη αυτόματης διαμόρφωσης διακομιστών DNS (IPv4 & IPv6)
echo. Διαχείριση DNS διακομιστών IPv4 ^& IPv6 για το "%InterfaceName%"
echo.&&echo. # Επιλογές:
echo.[0] * Γράψτε τις IP DNS διευθύνσεις σας, χειροκίνητα
echo.[1] Quad9 DNS (free, private) (Malware Blocking, DNSSEC Validation)
echo.[2] Cloudflare DNS (free, private)
echo.[3] OpenDNS (free, private)
echo.[4] * Προεπιλεγμένοι διακομιστές DNS του Παρόχου υπηρεσιών Διαδικτύου [ISP]
echo.        (Επαναφορά στην αρχική ρύθμιση του [ISP] - DHCP, Προεπιλογή.)
echo.[5] Εμφάνιση λεπτομερών πληροφοριών σχετικά με τις συνδέσεις δικτύου σας.
echo.
choice /c 012345 /n /m "Επιλογή #: "
echo.
if %errorlevel% equ 6 goto :6_
if %errorlevel% equ 5 goto :5_
if %errorlevel% equ 4 goto :4_
if %errorlevel% equ 3 goto :3_
if %errorlevel% equ 2 goto :2_
if %errorlevel% equ 1 goto :1_
:1_ [0]
start "" https://duckduckgo.com/?q=free+privacy+DNS
start "" https://quad9.net/service/service-addresses-and-features/#rec
set /p DNSv4pimary=Γράψε τον πρωτεύοντα (primary) IPv4 DNS:
set /p DNSv4alter=Γράψε τον εναλλακτικό (alternate) IPv4 DNS:
echo.  (ή πατήστε απλώς [Enter] για την ΜΗ επιλογή των IPv6)
set /p DNSv6pimary=Γράψε τον πρωτεύοντα (primary) IPv6 DNS:
set /p DNSv6alter=Γράψε τον εναλλακτικό (alternate) IPv6 DNS:
goto :_Next
:2_ [1]
set DNSv4pimary=9.9.9.9 && set DNSv4alter=149.112.112.112
set DNSv6pimary=2620:fe::fe && set DNSv6alter=2606:4700:4700::1001
echo. Quad9 DNS:
goto :_Next
:3_ [2]
set DNSv4pimary=1.1.1.1 && set DNSv4alter=1.0.0.1
set DNSv6pimary=2606:4700:4700::1111 && set DNSv6alter=2606:4700:4700::1001
echo. Cloudflare DNS:
goto :_Next
:4_ [3]
set DNSv4pimary=208.67.222.222 && set DNSv4alter=208.67.220.220
set DNSv6pimary=2620:119:35::35 && set DNSv6alter=2620:119:53::53
echo. OpenDNS :
goto :_Next
:5_ [4]
netsh interface ipv4 set dnsserver "%InterfaceName%" dhcp
netsh interface ipv6 set dnsserver "%InterfaceName%" dhcp
echo. Προεπιλεγμένοι διακομιστές Παρόχου υπηρεσιών Διαδικτύου [ISP]:
goto :_Next
:6_ [5]
goto :ipconfig
:_Next

:: IPv4 (πρωτεύων & εναλλακτικός)
echo.
echo. Αλλαγή πρωτεύοντος IPv4 σε %DNSv4pimary%
netsh interface ipv4 set dnsservers "%InterfaceName%" static %DNSv4pimary% primary >nul
echo. Αλλαγή εναλλακτικού IPv4 σε %DNSv4alter%
netsh interface ipv4 add dnsservers "%InterfaceName%" %DNSv4alter% index=2 >nul

:: IPv6 (πρωτεύων & εναλλακτικός)
echo. Αλλαγή πρωτεύοντος IPv6 σε %DNSv6pimary%
netsh interface ipv6 set dnsservers "%InterfaceName%" static %DNSv6pimary% primary >nul
echo. Αλλαγή εναλλακτικού IPv6 σε %DNSv6alter%
netsh interface ipv6 add dnsservers "%InterfaceName%" %DNSv6alter% index=2 >nul

:: Διαγραφή προσωρινής μνήμης της επίλυσης DNS και επιβεβαίωση της εφαρμογής των νέων τροποποιημένων ρυθμίσεων των διακομιστών DNS.
ipconfig /flushdns

echo.&&echo. Εμφανίστε λεπτομερείς πληροφορίες σχετικά με τις συνδέσεις δικτύου σας:
echo. Πατώντας [5] στο Αρχικό Μενού Επιλογών ...
timeout /t 8
goto :Start

:ipconfig
:: Εμφάνιση λεπτομερών πληροφοριών σχετικά με τις συνδέσεις δικτύου σας.
echo.&&echo. Λεπτομερείς πληροφορίες σχετικά με τις συνδέσεις δικτύου σας:
echo.&&echo. * Ρίξτε μιά ματιά γιά:
echo. Δωρεάν Ασφαλής-Ιδιωτικότητας Διακομιστές "DNS IP Servers"
echo. Αναζήτηση γιά: "Free Privacy DNS Servers" ...
start "" https://duckduckgo.com/?q=free+privacy+DNS

echo.&&echo. * Ρίξτε μιά ματιά στις πληροφορίες γιά το:
echo. "Quad9 DNS" (Δωρεάν, Ασφαλής-Ιδιωτικός Διακομιστής)
echo. (DNS IP Servers)
echo. Διαβάστε εδώ: "quad9.net" ...
echo. https://quad9.net/service/service-addresses-and-features/#rec
start "" https://quad9.net/service/service-addresses-and-features/#rec

echo.&&echo. * Συνολική Διαμόρφωση Συνδέσεων Windows IP (ΟΛΕΣ):
echo. Δείτε στο παράθυρο που θα ανοίξει.
echo. [Command Prompt - ipconfig /all] ...
start "ipconfig /all" %windir%\system32\cmd.exe /k ipconfig /all

echo.&&echo. * Διαδρομή Ρυθμίσεων - Ιδιοτήτων - Λεπτομερειών:
echo. Control Panel ^> (All Control Panel Items) ^>
echo. Network and Sharing Center ^> Connections: ^>
echo. Connections: ^>
echo. Details... or Properties, etc.
echo.
echo.&&echo. Πατήστε οποιοδήποτε πλήκτρο για επιστροφή στο Αρχικό Μενού Επιλογών...
pause >nul

goto :Start
exit